How to install and run Samsung Notes on Windows 11

Update

Please Note: With the new Samsung Notes updates, the previous method described below no longer works. Here’s the updated method to install an older version of Samsung Notes:

1. Deactivate Automatic Updates in Microsoft Store

   To prevent automatic updates in the Microsoft Store, follow these steps:

   • Open the Microsoft Store.
   • Click on your profile picture.
   • Navigate to “Settings.”
   • Turn off automatic app updates.

   

2. Download the Old Samsung Notes Version

   To install an older version of Samsung Notes, you can use the following method:

   • copy the following link: (https://apps.microsoft.com/detail/9NBLGGH43VHV)
   • Go to the website and paste the link store.rg-adguard.net.
   • Scroll down to find “SAMSUNGELECTRONICSCoLtd.SamsungNotes_4.3.150.0neutral~_wyx1vj98g3asy.msixbundle.”
   • Click on it to download the file.

   

3. Install the Old Version

   After downloading the Samsung Notes file, double-click on it to install the older version.

By following these steps, you can successfully install and use an older version of Samsung Notes on your Windows 11 computer.

Introduction

Samsung Notes is a popular note-taking application developed by Samsung Electronics. It allows users to create and manage notes, drawings, and other digital content. While the app was originally available on Windows 11, Samsung later restricted it to work exclusively on Samsung Galaxy Books. In this tutorial, we’ll show you how to install and run Samsung Notes on Windows 11, even if you don’t own a Samsung Galaxy Book.

Two Problems Installing and Running Samsung Notes

Before we dive into the installation process, it’s essential to address the two main challenges users face when trying to install and run Samsung Notes on non-Samsung devices:

1. Installation from Microsoft Store: While Samsung Notes is listed on the Microsoft Store, attempting to install it on a non-Samsung laptop often results in the “Install” button not appearing.

2. Compatibility Issue: Even if you manage to install Samsung Notes, you’ll encounter an error message stating, “This app only works with Galaxy Book” when attempting to run it.

   How to Install Samsung Notes

Installing Samsung Notes on Windows 11 is relatively straightforward, and you don’t need admin privileges to do it. Follow these steps:

1. Right-click the Start menu and click “Terminal” or “Windows Terminal.”

2. In the terminal window, type the following command:

   winget install "Samsung Notes"
   

3. Press “Enter” to execute the command.

4. You will be prompted to agree to the license terms of the app. Type ‘Y’ and press “Enter” to proceed.

5. The installation process will begin, and once completed, you can close the Terminal window. Samsung Notes will now be accessible from your Start menu.

How to Run Samsung Notes

After successfully installing Samsung Notes, you’ll still face the “This app only works with Galaxy Book” error when attempting to run it. To bypass this restriction, you can use the GalaxyBookMask project available on GitHub.

GalaxyBookMask GitHub Project

The GalaxyBookMask project provides three versions to help you run Samsung Notes:

1. Startup Version: Automatically masks the BIOS in the registry, enabling you to start Samsung Notes.

2. Non-Startup Version: Similar to the startup version but without automatically running at system startup.

3. Direct Launch Version: Launches Samsung Notes after editing the registry and then restores the registry to its original state after the app has been launched. It’s more like a shortcut to Samsung Notes.

You can find the GalaxyBookMask project on GitHub at https://github.com/kellwinr/galaxybook_mask.

To get started, you can download the BAT files directly from the GalaxyBookMask GitHub project, or you can create your own BAT files by copying the provided code into a text file and renaming it with a .bat extension.

Info: These script are editing your BIOS manufacturer in registry, it will likely automaticly reset with a restart. Using the methods described in this tutorial to install and run Samsung Notes on non-Samsung devices involve modifying system settings and editing the Windows registry. These actions can have unintended consequences and potentially impact the stability and performance of your computer. Before proceeding, we strongly recommend creating backups of your registry. Additionally, only use these methods if you fully understand the risks involved and are comfortable with the potential consequences. The author and publisher of this tutorial are not responsible for any issues, data loss, or damage that may occur as a result of following these instructions. Use this information responsibly and at your own discretion.

GalaxyBookMask (No Startup).bat

Similar to the startup version, but it doesn’t run automatically at system startup, giving you more control over when to enable Samsung Notes.

:: Set the parameters
set "params=%*" && cd /d "%~dp0" && pushd "%~dp0" && ( if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs" ) && fsutil dirty query %systemdrive% 1>nul 2>nul || ( echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~sdp0"" && %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && exit /B )

:: Mask the BIOS in the registry to appear as a Samsung Galaxy Book
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemProductName /t REG_SZ /d "NP960XFG-KC4UK" /f
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemManufacturer /t REG_SZ /d "Samsung" /f

:: Exit
exit

GalaxyBookMask.bat

Startup Version: This version automatically masks the BIOS in the registry at startup, allowing you to start Samsung Notes as if you were using a Samsung Galaxy Book.

:: Set the parameters
set "params=%*" && cd /d "%~dp0" && pushd "%~dp0" && ( if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs" ) && fsutil dirty query %systemdrive% 1>nul 2>nul || ( echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~sdp0"" && %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && exit /B )

:: Mask the BIOS in the registry to appear as a Samsung Galaxy Book
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemProductName /t REG_SZ /d "NP960XFG-KC4UK" /f
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemManufacturer /t REG_SZ /d "Samsung" /f

:: Copy the script to the Windows Startup folder for automatic execution
copy "GalaxyBookMask.bat" "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp" /Y

:: Exit
exit

SamsungNotes-DirectLaunch.bat

This version acts as a shortcut to Samsung Notes. It edits the registry temporarily, launches the app, and then restores the registry directly to its original state.

:: Set the parameters
set "params=%*" && cd /d "%~dp0" && pushd "%~dp0" && ( if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs" ) && fsutil dirty query %systemdrive% 1>nul 2>nul || ( echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~sdp0"" && %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && exit /B )

:: Store the previous system product name and system manufacturer
for /f "tokens=2*" %%a in ('reg query "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemProductName ^| find "REG_SZ"') do set "prev_product_name=%%b"
for /f "tokens=2*" %%a in ('reg query "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemManufacturer ^| find "REG_SZ"') do set "prev_manufacturer=%%b"

:: Mask the BIOS in the registry to appear as a Samsung Galaxy Book
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemProductName /t REG_SZ /d "NP960XFG-KC4UK" /f
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemManufacturer /t REG_SZ /d "Samsung" /f

:: Start Samsung Notes
start shell:AppsFolder\SAMSUNGELECTRONICSCoLtd.SamsungNotes_wyx1vj98g3asy!App

:: Wait for Samsung Notes to start
timeout /t 2

:: Restore the previous system product name and system manufacturer
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemProductName /t REG_SZ /d "%prev_product_name%" /f
reg add "HKLM\HARDWARE\DESCRIPTION\System\BIOS" /v SystemManufacturer /t REG_SZ /d "%prev_manufacturer%" /f

:: Exit
exit

Enjoy using Samsung Notes on your Windows 11 PC!